function FindUserIdForBot(const aUserName: string): string;
var Updates: TJSonArray;
  i: integer;
  s, ChatTYpe: string;
  Client: THTTPClient;
  JSon, Update: TJSonObject;
begin
  Result := '';
  Client := THTTPClient.Create();
  try
    try
      s := Client.Get(Format('https://api.telegram.org/bot%s/getUpdates', [CurBotId])).ContentAsString();
      JSon := TJSonObject.ParseJSONValue(s) as TJSonObject;
      try
        Updates := JSon.Values['result'] as TJsonArray;
        for i := 0 to Updates.Count - 1 do
        begin
          if (Updates[i] as TJSonObject).FindValue('message.chat') <> nil then
          begin
            Update := (Updates[i] as TJSonObject);
            ChatType := Update.FindValue('message.chat.type').Value;
            if (ChatType = 'group') or (ChatType = 'supergroup') then
            begin
             if Update.FindValue('message.chat.title').Value = aUserName then
             begin
               Result := Update.FindValue('message.chat.id').Value;
               break;
             end;
            end
            else
            if (ChatType = 'private') and (Update.FindValue('message.chat.username').Value = aUserName) then
            begin
              Result := Update.FindValue('message.chat.id').Value;
              break;
            end;
          end;
        end;
      finally
        Json.Free;
      end;
    except
      on E: Exception do Result := ''; //для ПТ: сообщение об ошибке выводится в функции, которая эту использует, в зависимости от результата
    end;
  finally
    Client.Free;
  end;
end;